%let name=hebrew;
filename odsout '.';

options validvarname=v6 validvarname=upcase; 
goptions reset=global;

data popdata; 
length age_grp $ 3;
length sex $ 10;
input totPOP arabPOP    AGE_GRP     SEX;
cards;
 -10    -1     G01      Male  
 -20    -2     G02      Male  
 -40    -3     G03      Male  
 -60    -3     G04      Male  
 -71    -4     G05      Male  
 -90    -5     G06      Male  
 -95    -12    G07      Male  
-130    -16    G08      Male  
-171    -18    G09      Male  
-180    -22    G10      Male 
-188    -32    G11      Male  
-196    -40    G12      Male  
-231    -48    G13      Male  
-270    -56    G14      Male  
-275    -57    G15      Male  
-290    -61    G16      Male 
-297    -75    G17      Male  
-319    -89    G18      Male  
-350    -102   G19      Male  
  16     1     G01      Female
  27     2     G02      Female
  51     3     G03      Female
  85     5     G04      Female
  93     7     G05      Female
 103     9     G06      Female
 104     10    G07      Female
 141     15    G08      Female
 187     18    G09      Female
 192     22    G10      Female
 194     30    G11      Female
 200     39    G12      Female
 231     45    G13      Female
 266     52    G14      Female
 266     53    G15      Female
 275     59    G16      Female
 282     72    G17      Female
 302     85    G18      Female
 332     99    G19      Female
;
run;

data popdata; set popdata;
pop=arabpop; grouping=trim(left(sex))||'_arab'; output;
pop=totpop-arabpop; grouping=trim(left(sex))||'_jews'; output;
run;

data work.anno;
length function style color $8;
retain xsys '2' ysys '1'  when 'b' style 'solid';

function='move'; x=0; y=0; output;
function='bar'; x=350;  y=100;  color='cxf4e4e4'; output;

function='move'; x=0; y=0; output;
function='bar'; x=-350;  y=100;  color='cxd4ecfc'; output;

run;

 
proc format; picture posval low-high='000,009'; run; 

data popdata; set popdata;
age_range='     ';
if age_grp eq 'G19' then age_range='0-4';
if age_grp eq 'G18' then age_range='5-9';
if age_grp eq 'G17' then age_range='10-14';
if age_grp eq 'G16' then age_range='15-19';
if age_grp eq 'G15' then age_range='20-24';
if age_grp eq 'G14' then age_range='25-29';
if age_grp eq 'G13' then age_range='30-34';
if age_grp eq 'G12' then age_range='35-39';
if age_grp eq 'G11' then age_range='40-44';
if age_grp eq 'G00' then age_range='45-49';
if age_grp eq 'G09' then age_range='50-54';
if age_grp eq 'G08' then age_range='55-59';
if age_grp eq 'G07' then age_range='60-64';
if age_grp eq 'G06' then age_range='65-69';
if age_grp eq 'G05' then age_range='70-74';
if age_grp eq 'G04' then age_range='75-79';
if age_grp eq 'G03' then age_range='80-84';
if age_grp eq 'G02' then age_range='85-89';
if age_grp eq 'G01' then age_range='90+';
length myhtml $400;
myhtml='title='|| quote( 
  'Age Group: '||age_range||'0D'x||
  'Sex & Race: '||grouping||'0D'x||
  'Population for this age/sex/race: '||put(pop,posval.)||'0D'x||
  ' ------------------- '||'0D'x||
  ' Population for this age/sex: '||put(totpop,posval.)||'0D'x||
  ' Population for this age/sex (Jews & Other): '||put(totpop-arabpop,posval.)||'0D'x||
  ' Population for this age/sex (Arab Population): '||put(arabpop,posval.)||'0D'x||
  ' ') ||
 ' href='||"http://www.mfa.gov.il/mfa"||' '
 ;
run;


options nocenter;
proc print data=popdata noobs; 
var pop age_grp sex;
run;

 GOPTIONS DEVICE=gif;
 
 ODS LISTING CLOSE;
 ODS HTML path=odsout body="&name..htm"
 (title="Hebrew example")
 gtitle nogfootnote
 style=d3d
 ;
 goptions border;
 goptions cback=white;

axis2 order=(-350 to 350 by 50) offset=(0,0)
 label=(f="arial/bold" "Thousands   " 
        f=hebrew  'EDE9F4ECE0'x
        )
 value=( f="arial" h=2.5)
;

axis1 
 label=(h=3 f="arial/bold" j=c 'Age' 
            f=hebrew j=c 'ECE9E2'x) 
 value=( f="arial" h=2.5 
' 90+ ' 
'85-89' 
'80-84' 
'75-79' 
'70-74' 
'65-69'  
'60-64' 
'55-59' 
'50-54' 
'45-49' 
'40-44' 
'35-39' 
'30-34' 
'25-29' 
'20-24'  
'15-19' 
'10-14' 
' 5-9 ' 
' 0-4 ') ; 

legend1 mode=protect position=(top left inside) across=1
  label=none offset=(2,-1) frame cframe=white shape=bar(2,2)
  value=(h=3
   'Arab population' 
   'Jews and others' 
   font=hebrew 
   'FAE9E1F8F620E4E9E9E8E5ECEBE5E0'x
   'EDE9F8E7E0E520EDE9E6E5E4E9'x
   )
;

pattern1 v=s c=cx64c48c; 
pattern2 v=s c=cx04acec;   
pattern3 v=s c=cx64c48c; 
pattern4 v=s c=cx04acec;   

goptions htitle=3pct htext=3pct ftext="arial/bold" gunit=pct;

title1 j=c font=hebrew 
  'ECE9E2E5'x
  '20EFE9EE'x
  '202CE4E9E9E8E5ECEBE5E0'x
  '20FAF6E5E1F7'x 
  '20E9F4EC'x 
  '202CE4E9E9E8E5ECEBE5E0'x
  '20202E31'x
;

title2 "1. Population, by Population Group, Sex and Age";
title3 h=2pct "31.12.2002";
title4 h=2pct " ";

title5 j=c font=hebrew 'E4E9E9E8E5ECEBE5E0E4'x 
                       '20ECEB'x;

title6 j=l "          Males    " 
       font=hebrew 'EDE9F8EBE6'x
       j=c font="arial/bold" "Total Population" 
       j=r "Females "  
       font=hebrew 'FAE5EBF7F020202020'x
       ;

/*
footnote j=c link="http://194.90.153.197/shnaton54/dia02_01e.shtml"
 "Imitation of the following hebrew graph [click here]";
*/

footnote j=c "Using the new/changed v9.1 'hebrew' sas/graph software font";

proc gchart data=popdata; 
format pop posval.; 
hbar age_grp / discrete 
  space=.3 subgroup=grouping maxis=axis1 raxis=axis2 
  type=sum sumvar=pop 
  nostats 
  frame /* cframe=white */
  caxis=black 
  coutline=same 
  legend=legend1
  autoref cref=gray clipref
  annotate=work.anno 
  html=myhtml
  des="" name="&name"; 
label age_grp='00'x; 
run; 


 quit;
 ODS HTML CLOSE;
 ODS LISTING;