%let name=japan;
filename odsout '.';

data work.a;
input x linetype y1;
cards;
0  1 99.8
1  1 99.8
2  1 99.5 
3  1 99.2
4  1 99.4
5  1 99.6
6  1 99.3
7  1 99.0
8  1 99.4
9  1 99.2
10 1 99.2
11 1 98.8
12 1 98.7
0  2 98.4
1  2 98.2
2  2 97.8 
3  2 98.0
4  2 98.3
5  2 98.6
6  2 98.5
7  2 98.2
8  2 98.4
9  2 98.4
10 2 98.1
11 2 98.1
12 2 98.1
0  3 98.2
1  3 97.9
2  3 97.6 
3  3 97.9
4  3 98.2
5  3 98.4
6  3 98.1
7  3 98.0
8  3 98.1
;
run;

/* These are the japanese character values that get printed in the legend,
   in the top/left inside of the graph */
data work.a; set work.a;
if linetype eq 1 then jlinetype='95BD'x||'90AC'x||'8250'x||'8252'x||'944E'x;
if linetype eq 2 then jlinetype='95BD'x||'90AC'x||'8250'x||'8253'x||'944E'x;
if linetype eq 3 then jlinetype='95BD'x||'90AC'x||'8250'x||'8254'x||'944E'x;
run;


/* Define a template - Use brown 3d border rather than gray ... */

/*
I listed out the default d3d style template using the following code:

 proc template; 
  source styles.d3d;
 run;

And then I modified it using the following code:
*/
ods path work.template(update) sashelp.tmplmst;
proc template;
 define style styles.brown3d;
   parent = styles.d3d;

   replace Output from Container /
      borderstyle = outset
      background = colors('tablebg')
      bordercolordark = liolbr
      bordercolorlight = liybr
      borderwidth = 9
      rules = all
      frame = Box
      cellpadding = 5
      cellspacing = 1
      bordercolor = colors('tableborder');

 end;
run;



 GOPTIONS DEVICE=gif;
 
 ODS LISTING CLOSE;
 ODS HTML path=odsout body="&name..htm"
 (title="Japanese example")
 style=brown3d
 gtitle nogfootnote
 ;
 goptions border;

goptions htitle=6pct htext=3.25pct ftext="arial";
goptions hsize=6in vsize=5in;

/* I include the 2 blanks before title1 and after title2 to help add some spacing */

title1 link="http://www.stat.go.jp/data/cpi/sokuhou/tsuki/index-z.htm" 
  j=l font=kanji '  ' '  ' '907D'x '8250'x '  ' '918D'x '8D87'x '8E77'x '9094'x  '82CC'x '93AE'x '82AB'x ;

title2 j=r font=kanji '95BD'x '90AC'x '8250'x '8251'x '944E'x '8181'x '8250'x '824F'x '824F'x '  ' '  ';

/* I add a blank/fake title on the left & right side of the graph to add more spacing */
title3 a=90 h=3pct " ";
title4 a=-90 h=3pct " ";

/*
footnote link="http://www.stat.go.jp/data/cpi/sokuhou/tsuki/index-z.htm" 
  "SAS Imitation of the following kanji graph [click here]";
*/

/*
footnote2 link="kanjigraph.gif" "Specifically, the top/left graph in [this] gif.";
*/

axis1 order=(0 to 12 by 1) minor=none label=(j=r font=kanji '8C8E'x) 
  value=(tick=1 ' ') offset=(0,0) major=(height=-.5 cells);

axis2 order=(96 to 102 by 1) minor=none label=none offset=(0,0) major=(height=-.8 cells);

symbol1 c=black i=join v=none l=2;  /* dashed line */
symbol2 c=gray  i=join v=none;      /* solid gray line */
symbol3 c=black i=join v=none;      /* solid black line */

legend1 mode=share position=(top left inside) across=1 
  value=(font=kanji) label=none offset=(5,-1);

goptions cback=lilg;
 
proc gplot data=work.a ; 
 plot y1*x=jlinetype / 
  haxis=axis1
  vaxis=axis2
  legend=legend1
  cframe=lilg
  des='SAS/Graph using sas kanji software font characters' 
  name="&name" ; 
run;


 quit;
 ODS HTML CLOSE;
 ODS LISTING;