%let name=bar6;
filename odsout '.';

data a;
input ITEM $ 1-6 AMOUNT;
colorvar=amount/abs(amount);  /* 2 values ... one, or negative one */
cards;
ITEM A 11.8
ITEM B -10.5
ITEM C -8.8
ITEM D 6.8
ITEM E 4.2
ITEM F -2.3
;
run;

data a; set a;
length htmlvar $500;
htmlvar='title='||quote(
 'Item: '|| trim(left(Item)) ||'0D'x||
 'Amount: '|| trim(left(amount))
)
||' '||
 'href="bar7.htm"';
run;


 GOPTIONS DEVICE=gif;
 
 ODS LISTING CLOSE;
 ODS HTML path=odsout body="&name..htm" (title="Deviation Bar Chart") style=minimal;
 goptions noborder;

goptions gunit=pct htitle=6 ftitle="albany amt/bold" htext=4.25 ftext="albany amt/bold";

axis1 label=none;
axis2 label=('AMOUNT') order=(-12 to 12 by 4) minor=(number=1) offset=(0,0);

/* pattern v=solid color=red; */
pattern1 v=solid color=cxbd0026;  /* reddish color */
pattern2 v=solid color=cx43a2ca;  /* this is the hex rgb color for mild blue */

title "Deviation Bar Chart";
proc gchart data=a; 
hbar item / discrete 
 type=sum sumvar=amount 
 subgroup=colorvar  /* control the color of the bars */
 nostats
 maxis=axis1 /* midpoint axis */
 raxis=axis2 /* response/numeric axis */
 autoref /* reflines at every major axis tickmark */
 clipref /* put reflines behind the bars */
 cref=graycc
 nolegend
 coutline=black 
 html=htmlvar
 des="" name="&name" ;  
run;


 quit;
 ODS HTML CLOSE;
 ODS LISTING;