%let name=bub1;
filename odsout '.';

data a;
length color $ 8;
input series $ 1-1 x y value;
cards;
A 1.0 1.0 .65
A 2.0 0.9 0.3
B 1.4 2.3 .65
B 2.2 1.6 0.3
;
run;

data a; set a;
length html $500;
 html='title='||quote( 
  'X: '|| trim(left(x)) ||'0D'x||
  'Y: '|| trim(left(y)) ||'0D'x||
  'Value: '|| trim(left(value)) ||'0D'x||
  'Series: '|| trim(left(series))  
)
||' '||
 'href="bub2.htm"';
run;

/* Use annotate to do the 'bubbles' -- I would normally use
   the gplot bubble chart, but it does not support having bubbles with
   different colors in the same bubble chart.  Also, annotate allows me
   to have the html title= charttips and href= drilldown, which gplot bubble 
   chart does not support (see request S0171805) */
data annobub;
set a;
length function color  $8;
retain xsys ysys hsys '2' when 'a';
function='pie';
rotate=360;
if series eq 'A' then color='cx9999ff';
if series eq 'B' then color='cx993366';
size=value;
position='5';
style='psolid'; 
output;
/* add a black outline to the pie */
style='pempty'; color='black'; output;
run;

 GOPTIONS DEVICE=gif;
 
 ODS LISTING CLOSE;
 ODS HTML path=odsout body="&name..htm" (title="Bubble Plot") style=minimal;
 goptions noborder;

goptions gunit=pct htitle=6 ftitle="albany amt/bold" htext=4.25 ftext="albany amt/bold";

axis1 label=(a=90 'Y Axis') offset=(0,0) order=(0 to 3 by 1) minor=(number=1);
axis2 label=('X Axis') offset=(0,0) order=(0 to 3 by 1) minor=(number=1);

goptions xpixels=720 ypixels=600;

symbol i=none v=dot;

title "Bubble Plot";
proc gplot data=a anno=annobub; 
plot y*x=series / 
 autovref autohref cvref=gray chref=gray
 nolegend
 vaxis=axis1
 haxis=axis2
 des="" name="&name" ;  
run;

 quit;
 ODS HTML CLOSE;
 ODS LISTING;