%let name=clin1;
filename odsout '.';

data a;
input x y1 y2;
cards;
1 1.0 5.0
2 2.0 7.0
3 3.0 8.0
;
run;

data a; set a;
length htmlvar $500;
 htmlvar='title='||quote(
  'X: '|| trim(left(x)) ||'0D'x||
  'Column Y: '|| trim(left(y1)) ||'0D'x||
  'Line Y: '|| trim(left(y2))
)
||' '||
 'href="col1.htm"';
run;


GOPTIONS DEVICE=gif;
ODS LISTING CLOSE;
ODS HTML path=odsout body="&name..htm" (title="Line & Column Chart") style=minimal;
goptions noborder;

goptions gunit=pct htitle=6 ftitle="albany amt/bold" htext=4.25 ftext="albany amt/bold";
goptions xpixels=650 ypixels=600;

title1 "Line & Column";
title2 "Classic Combination Chart";

pattern1 v=solid color=cx993366;  

symbol1 interpol=join width=3 value=dot height=4 color=navy;  

axis1 label=(a=90 'Column Axis') offset=(0,2) order=(0 to 3.5 by .5) major=(h=-1) minor=none;
axis2 label=(a=90 'Line Axis') offset=(0,2) order=(0 to 9 by 1) major=(h=-1) minor=none;
axis3 label=('X Axis') offset=(13,13) order=(1 to 3 by 1) minor=none;

proc gbarline data=a;
 bar x / discrete type=sum sumvar=y1 axis=axis1 maxis=axis3 
   space=5 width=4 html=htmlvar des="" name="&name" ;
 plot / type=sum sumvar=y2 axis=axis2 html=htmlvar;
run;

quit;
ODS HTML CLOSE;
ODS LISTING;