%let name=gasoline;
filename odsout '.';



filename datafile url "http://www.fuelgaugereport.com/sbsavg.asp"
 proxy='http://inetgw.fyi.sas.com:80';

data mydata;
infile datafile /* firstobs=10 */ pad;
input wholeline $ 1-200;
/* Just output the lines for the state data */
if index(wholeline,'<tr><td><a href="')=1 then output;
run;


/* Parse the state name & gas price data out of the line of html table text */
data mydata; set mydata;
st=substr(wholeline,18,2);
length statename $20;
statename=stnamel(st);
format regular_gas_price dollar7.2;
regular_gas_price=scan(scan(wholeline,2,'$'),1,'<');
run;



/* Read in the population data for each state */
filename stateurl url "http://www.census.gov/population/projections/state/stpjpop.txt"
 proxy='http://inetgw.fyi.sas.com:80';
data statedata;
infile stateurl firstobs=10 obs=60 pad;
input wholeline $ 1-200;
length statename $20;
statename=scan(wholeline,1,'.');
population=input(scan(substr(wholeline,21),3,' '),comma10.0);
population=population*1000;
run;

/* Merge the population data in with the gasoline data */
proc sql;
create table mydata as 
select mydata.*, statedata.population
from mydata left join statedata
on mydata.statename = statedata.statename;
quit; run;


data mydata; set mydata;
length myhtml $1000;
myhtml='title='||
quote(
'State: '||trim(left(statename))||'0D'x||
'Population: '||trim(left(put(population,comma20.0)))||'0D'x||
'Regular Gas Price: '||trim(left(put(regular_gas_price,dollar7.2)))
)
||' '||
'href="http://www.fuelgaugereport.com/'||trim(left(upcase(st)))||'avg.asp"'
;
run;


data us;
set maps.us;
st=fipstate(state);
run;


/* Use the macro to creat the sas/graph map data set for this tree map */
/* I'm sizing the blocks based on the state population, and in the gmap I'll color them by gas price */
libname here '.';
proc datasets lib=here nolist nowarn; delete gasmap; run;
%include 'treemap_inc.sas';
%mini_tree(mydata,st,population,here.gasmap,0,0,160,100);
/*
*/

/* 100x100 is square - I do 180x100 to fit the available space better */


/* Create annotate data set for state abbreviations */
%include 'treeanno2_inc.sas';
%treelabel2(here.gasmap,st,black,annolabel);

/* 
Use the new v9.2 support of ods styles, to do the color gradient
*/
proc template;
define style styles.mygradient;
  parent=styles.listing;
  style twocolorramp / startcolor=yellow endcolor=red;
end; run;




 GOPTIONS DEVICE=gif;
 
 ODS LISTING CLOSE;
 ODS HTML path=odsout body="&name..htm" (title="Gas Prices - July 1, 2008") style=mygradient;

 
 goptions gunit=pct ftitle="arial/bold" ftext="arial" htitle=4 htext=2.5;

 title1 "Regular Gasoline Prices";
 title2 ls=1.2 link="http://www.fuelgaugereport.com/sbsavg.asp" "Data Source: AAA" link='' "  (&sysdate9)";

 footnote1 "size=state population       color=gas price";
 footnote2 h=.2 " ";

 legend1 label=none shape=bar(.15in,.15in);

 proc gmap data=mydata map=here.gasmap; 
 id st; 
 choro regular_gas_price / 
 anno=annolabel
 html=myhtml coutline=grayaa woutline=2
 legend=legend1
 des="" name="&name"; run;

 footnote;
 proc gmap data=mydata map=us;
 id st;
 choro regular_gas_price /
 html=myhtml coutline=grayaa 
 legend=legend1
 des="" name="&name"; run;

 proc sort data=mydata;
 by descending regular_gas_price;
 run;
 proc print data=mydata; 
 format population comma20.0;
 var statename regular_gas_price population;
 run;

 quit;
 ODS HTML CLOSE;
 ODS LISTING;